*label ch2_tavern

*page_break
The tavern is filled with soldiers. The rowdy atmosphere…

*fake_choice
    #...is almost titillating. It reminds me of my father's men.
        I used to visit my father and his men in our village tavern. It wasn't much, the hut was much smaller than this one, but the different hides and pelts gave it a warm feeling in the midst of winter winds. Here, however, two deer pelts litter the floor and they're filled with holes. The tanning of the hides look sloppy and cheap. 
        
        Still, there's something familiar: the rambling of the drunk men is exactly the same. It's nice, I suppose.
    #...is annoying. Why am I here?
        I bite my lip and try to remember the reason I even wandered here. I glance at the door. Is it too late too just turn around and—
    #...doesn't make me feel much at all.
        I need to meet the men from my contubernium and leave. Easy enough.

*if (marcus_voices) or (ch2_niall_undermine)
    "Haa-Tii!" We were waiting for you!" A familiar high-pitched shriek calls as soon as I step into the room. Kegan peers at me, his face lightly flushed. How did he have time to drink already?
    *goto c2_kegan_drink
    
*else
    "Come sit with us!" A familiar high-pitched shriek calls to me not long after I departed from our entourage. Kegan peers at me, his face lightly flushed. How did he have time to drink already?
    *goto c2_kegan_drink
    
*label c2_kegan_drink
"Aren't you too young to drink?"

"Aren't I too young to kill people?"

Floyd snorts next to him. I hate to admit, but he's got a point. He's chunk down only one beer so far, but his eyes are already glassy. And apparently he's a snarky drunk.

Floyd shakes his head with a smile. "I won't allow him any more drinks."

Kegan frowns at the implication. "I'm not a child!"

"If you have to tell me you're not one, there's a high chance you are."

The boy squints his eyes at the wisdom he's been imparted with before pouting. "Fine." 

The other men from our squad are busy with the drinking, too, and only Pec gives me a small nod as our eyes meet.

Soon, however, Quinn catches my eyes. $!{q_he} beckons me to join ${q_him}.

*page_break
Quinn sits alone with a pint. $!{q_he} calls the waiter passing by: "Oy! Bring me another beer." $!{q_he} has a plate of cookies in front of ${q_him}.

"When did you start to drink? Didn't you always say that it clouds people's judgment?"

"Well I'll be damned." $!{q_he} takes a look at ${q_his} newly filled pint. "It sure looks like I have."

Instinctively I roll my eyes at ${q_him}. "No need for theatrics." 

"Sorry." $!{q_he} grins to the pint and stuffs a cookie in ${q_his} mouth. "I have no need for pesky judgment. I've clearly lost it since I'm here. With all of these… people." $!{q_he} spits out the word 'people' with a sneer.

"I suppose you have. Both of us have."

"Here's to that." $!{q_he} raises ${q_his} cup and gulps the rest of the pint with one go. "Don't you want one?"

"A beer? I need to have a clear head."

"No, not beer. A cookie."

I peer at the honey-cookie on ${q_his} hand.

*if broken
    The sight makes something churn in my stomach. Impulsively I check the condition of my teeth, smooth against my tongue and all of them intact.
    
    Quinn frowns at me. "What's wrong? It's just a cookie."
    
    *fake_choice
        #Tell what my mother used to say.
            "I don't eat sweets."
            
            "I know, but it's just one cookie. It's really good. You refused the cookies I tried to buy you the other day and—"
            
            "Mother—"
            
            $!{q_he} grimaces at the word. $!{q_he} didn't like my mother. $!{q_he} never said it out loud, but I knew it. $!{q_his} frame tensed every time mother called me for my lessons. "What about her?"
            
            "She said the Twins will abandon me if I eat sweets." As the words leave my mouth, a surge of embarrassment tries to take over me. Is it a foolish thought? Would they abandon me for something so trivial? Am I still a child to believe such a thing?
            
            Quinn's pint stops half-way on the way to ${q_his} mouth, ${q_his} brows raised. I'm expecting a sympathetic frown, a—
            
            Instead, ${q_he} starts laughing. $!{q_his} laughter is so loud, it draws the attention of the nearby customers. 
            
            *fake_choice
                #"It's not funny. How do you know about what the gods want?"
                    I know it's almost ridiculous to defend my case, I know it sounds like it, but ${q_his} laughter puts me on defense. However, it only makes ${q_him} laugh even harder. By now tears are forming in the corners of ${q_his} eyes.
                    
                    It's not that funny.
                #Frown.
                    I didn't expect ${q_him} to laugh at my peril, even if I know it's ridiculous.
                #"I suppose it's kind of stupid..."
                    $!{q_he} shakes ${q_his} head through ${q_his} laughter. "It is!"
                    
            "Just… give me a moment," ${q_he} laughs through ${q_his} tears and starts pinching ${q_his} cheeks. After a few more fits of muffled laughter, ${q_he} gathers ${q_him}self. "Listen." $!{q_he} straightens ${q_his} posture. "I have in good authority that the Twins don't give two hoots whether or not you eat cookies."
            
            "How would you know it better than her? She was the chief druid, she knew everything about the Twins."
            
            Quinn merely smiles and shakes ${q_his} head. "Trust me."
                       
            *fake_choice
                #Trust ${q_him} and take the cookie.
                    *set broken_rebel true
                    "Fine." I grit my teeth and take the damn cookie and shove it in my mouth. 
                    
                    "Hey, hey, no need for such force," Quinn laughs.
                    
                    The sweetness of the cookie spreads quickly across my tastebuds, coating my mouth with saliva. It's good. I wonder why the gods would deny me such a treat?
                    
                    The gods… I halt my breathing and wait.
                    
                    "BOO!!"
                    
                    *page_break
                    
                    I jump on my seat. "Quinn, for the love of—"
                    
                    The perpetrator bursts into laughter, having scared the living shit out of me.
                    
                    "I couldn't help it, I'm almost sorry," ${q_he} chuckles, evidently more than happy with ${q_him}self. "But see? No lightning struck you down." 
               
                    And indeed, there's no lightning. I check my teeth with my tongue just to be sure. It's ridiculous, but I have to. They're still there. Did mother lie to me? 
                    
                    Why?
                #Refuse the cookie.
                    *set still_broken true
                    I still shake my head. How would ${q_he} know better than mother? 
                    
                    Quinn frowns, but nods. "Fine." $!{q_he} lowers ${q_his} voice, and I barely make out ${q_his} muttering: "She's still in your head."
                    
                    "What did you say?"
                    
                    "Nothing."
        #Change the subject.
            
*if rebel
    The sight makes something churn in my stomach, but still my hand moves to take the offered cookie. It doesn't matter if I want it, what matters is that I can take it. No lightning struck me down the other time, neither will it now.
    
    "Why are your brows so furrowed? It's just a cookie!" Quinn laughs, but I don't return it. This, in turn, makes Quinn return the frown. "What's wrong? You ate the cookies the other day with a similar grimace on your face. I don't want to force you if you hate cookies."
    
    "I don't hate them. I just…"
    
    *fake_choice
        #Tell ${q_him} about what mother said.
            "Mother used to say the Twins will abandon me if I eat sweets." The words leaving my lips prove to sound as ridiculous as they do in my head, still as stupid as when I told them to father. However, there's no sympathy in Quinn's face, no worried frown like father had. 
            
            Instead, there's only a rising fit of laughter. One that erupts with such strength that it draws the attention of the nearby customers. "The Twins," ${q_he} says through laughter, "will abandon you if you eat sweets."
            
            I nod, growing irritated. How could ${q_he} know anything about the gods?
            
            Quinn shakes ${q_his} head, wiping the tears from ${q_his} eyes. "I knew your mother was… stern, but this is just ridiculous."
            
            The statement makes me bite my lip, the thought of insulting her almost blasphemous.
            
            *fake_choice
                #Agree with Quinn.
                    "It's ridiculous," I admit. But it doesn't change the fact that I believed her for years. What else has she told me that wasn't true? Why did she lie to me in the first place?
                    
                    A sting of regret pierces my heart. I can't think like that about her.
                #"Maybe she just wanted to help me stay healthy?"
                    *set rebel_broken true
                    My mind tries to conjure up anything to defend her. "Or maybe she understood something about the gods wrong. Maybe it wasn't intentional."
                    
                    The last remnants of laughter disappear from Quinn's features, only to be replaced with something akin to sympathy and pity. "Why do you feel the need to defend her? She lied to you."
                    
                    "She's my mother."
                    
                    "…That she is."
        #Change the subject.
        
It's better to change the subject. "How many have you drunk already?"

"I didn't count."

Given ${q_his} lithe frame and low tolerance, this might become a problem.

The roaring laughter interrupts us. Pec passes by with a jug of beer on his hand smacking my back with his free one.

"Oy, Hati! Come sit with us! Brick is threatening to beat up the Legionaries next to our table."

Quinn's squinted eyes peer into the man and he hesitates. "Umm." He bends to whisper: "Join us if you want to. Don't wanna agitate your friend." With these words he flees the scene, dodging the tightly placed chairs and tables on his way. 

Quinn ignores the escape and turns ${q_his} attention to a brooding woman sitting in the corner of the room alone, sipping wine from a goblet. "Doesn't that woman look familiar to you?" 

Her brown hair and proud posture does look oddly familiar. Then it quickly comes to me: She looks like the woman I met in the baths when I was still a recruit. 

I nod slowly. Why does Quinn know who she is? "I think I met her. In the baths."

"Don't you think she looks like someone else, too?" Quinn asks without raising ${q_his} gaze from the plate of cookies. "Minus the hair?"

*fake_choice
    #"What do you mean?"
        Quinn shakes ${q_his} head, almost disapprovingly. "You should use your head more. It could save your life one day." Ignoring the insult, I stare at ${q_him}. $!{q_he} sighs. "She's clearly Camilla. I'd know that sneer from a mile away."
        
        Camilla? I suppose she looks like her, but it's hard to tell since she's not covered in makeup. Is it a wig that she usually wears?
        
        Quinn nods. "Of course it's a wig, you big dummy. You should go talk to her."
    #"I think I know who she is."
        Some of the braver soldiers try to approach her from time to time, but quickly retreat with glassy eyes and blanched faces. Her cold stare and a violent sneer does remind me of someone. 
        
        Quinn nods as the realization starts to take over me. "Our dear old ice queen herself."
        
        "Camilla. What is she doing here?"
        
        "Maybe you should ask her."
        
"Why?"
        
"Trust me."
        
"Why do you keep saying that?"
        
"What the worst that could happen? She's already your buddy. Besides, I haven't given you any reason not to trust me, right?"

*choice
    #"Fine."
        *goto ch2_tavern_camilla
    #"No."
        *goto ch2_tavern_nopecamilla
*page_break
*label ch2_tavern_nopecamilla
"No?"

"Why do you keep on trying to get me to know Camilla? What's your aim?"

"My aim? Hm." It's as if the question surprises ${q_him}, as if I would just follow ${q_his} every whim without question. "I suppose I just wanted you to better your chances of getting closer to…" $!{q_he} glances around, making sure no one is listening. "You know."

"I have other ways. She's not the only one close to him."

"What other ways? You mean that beefcake of a red head?"

"Niall? Maybe."

"Fine. I suppose I should trust you more." $!{q_he} sighs and stuffs another cookie into ${q_his} mouth. "You're right. We're a team. I can't just keep shoving you around."

Our conversation is disturbed when the whole tavern falls silent and everyone's eyes are drawn to the door. Instinctively, I follow the gazes of others: The Legate stares at the tables in a distraught state. Finally his gaze lands on the lone table in the corner: Camilla's.

The Legate stomps straight at Camilla's table, the three of his bodyguards scurrying behind him. He has a concerned look on his face, ignoring the flood of salutations almost blocking his way. The gazes of the patrons follow him and, in turn, focus on Camilla.

"Camilla, what are you doing here?" His voice is loud and resonant in the otherwise dead-silent tavern, so the onlookers can hear every word the couple is exchanging.

Camilla's gaze darts across the room like a caged animal. "I told you not to follow me here."

"I'm not following—"

"What do you think you're doing here, then?"

"This is a place for brutes and loose women, not one for—"

"They wouldn't know who I am if you didn't insist on following me. Whose fault is it, then, if they deem me a loose one?" She squints her eyes at Legate and gulps her goblet of wine with more vigor and less grace.

Finally the Legate escapes the scene as his wife is left alone with her drink, her face sour and hateful.

Quinn pokes me with ${q_his} index finger and winks. "Our Legate is having trouble at home. Whatever to do with this information…"
*goto ch2_tavern_brick

*label ch2_tavern_camilla
Camilla's gaze is already on me when I approach her lone table. She holds a wine goblet between her long fingers and gives me a small sneer. Not as prominent as the ones she gave to other soldiers approaching her, but a sneer nonetheless.

"Camilla?"

She raises her brow, a small smile forming on her lips. "Took you long enough. You aren't as dense as you look."
        
"Why are you in disguise?"
        
"This isn't my disguise. This is how I look. What do you want now?"

*fake_choice
    #"I'm not sure."
        *set clue+1
        Her eyes follow mine back to Quinn who by now has eaten all of ${q_his} cookies and ordered two more pints. The sight almost makes me sigh. I really don't want to carry ${q_him} back to the fort.
        *if build = "lithe" 
            I'm not even sure if I could. I'd have to ask Floyd for help.
        
        Camilla nods slowly. "Your… friend wanted us to talk?"
        
        *if ch1_quinn_wtf
            "Again, yes."
            
        She looks at Quinn for a long time before speaking: "There's something peculiar about ${q_him}, isn't there?"
        
        "What do you mean?"
        
        "I'm not sure. Like ${q_he}… doesn't belong here."
        
        I follow her gaze with a small frown. Quinn doesn't look any different from the rest of the patrons in the inn.
        
        "I'm not sure I follow—"
        
        She shakes her head. "Nevermind. Who among us belongs here, anyway?"
    #"Do you come here often?" [i]flirt[/i]
        There's something about her demeanor that makes me want to poke her, to get a reaction. She snorts at the question. "Are you seriously using age-old pickup lines on me?"
        
        "Would you hold it against me?"
        
        "I would suggest you to come up with better lines for the next time."
        
        "So there could be a next time?"
        
        Again an unbecoming voice escapes her, but she doesn't care. "I should have your head." 
        
        "It's too pretty for a pike."
        
        She cocks her head and takes a sip of her wine. "Indeed."
    #"You looked lonely." 
        *set ruthless -2
        She squints her eyes at me, as if waiting to see a sneer appear on my face. When no such thing happens, she sighs. 
        
        "Don't play me for a fool."
        
        "I'm not playing."
        
        "Then you're even more of a fool than I gave you credit for."
        
        Again with the insults. She tries her damnest to push me away. Should I just give her what she wants?
    #Just smile. I don't know what to say.
    #"I don't care for your insults."
        She squints her eyes at me. "Shouldn't you leave, then? Let me drink in peace."

Suddenly the already familiar expressionless mask hurries back to obscure her face. Her gaze is on the front door. Almost all the noise dies down in the tavern.

The Legate.

*page_break
The Legate stomps straight at Camilla's table, the three of his bodyguards scurrying behind him. He has a concerned look on his face, ignoring the flood of salutations almost blocking his way. The gazes of the patrons follow him and, in turn, focus on Camilla.

"Camilla, what are you doing here?"

Her gaze darts across the room like a caged animal. "I told you not to follow me here."

"I'm not following—"

"What do you think you're doing here, then?"

"This is a place for brutes and loose women, not one for—"

"They wouldn't know who I am if you didn't insist on following me. Whose fault is it, then, if they deem me a loose one?" She squints her eyes at Legate and gulps her goblet of wine with more vigor and less grace.

Legate shakes his head before his gaze turns to me. Slowly a realization clears his gaze. "Oh, you're the boy from earlier!"

He remembers me. I'm not sure if that's a good thing.

*if legate_name
    "Hati, right? What a nice surprise." He smiles and taps my arm. "You're a good lad, I remember." He bends over to me with a low voice: "I'm sorry you had to see this. She's being difficult."
    
*if not(legate_name)
    "I'm sorry, I didn't catch your name the last time."
    
    "My name is Hati, Lord Legate."
    
    "Nice to meet you, Hati. I'm sorry you had to see this. My wife is being most difficult."
    
Camilla shoots a deathly glare at the Legate, who quickly shuts his mouth.

He gathers his courage and opens the said mouth again: "I merely wanted to let you know that you missed dinner."

"I'm fully aware."

"But you need to—"

"I don't need to do anything, [i]dearest[/i] [i]husband[/i]." Her words ooze poison. 

The Legate seems to decide against continuing the discussion with a deep, tired sigh. "No, you don't. I'm sorry." He awkwardly looks back to me with a small, apologetic smile. "It was good to see you again, Hati."

I nod and he flees with his cloak billowing behind him.

Camilla returns her gaze back to the wine. "I want to be alone."

*fake_choice
    #"Are you sure?"
        Before I can finish my question, she shoots a glare at me with such ferocity that the words refuse to leave my mouth. I nod and leave.
    #"Do you need anything?"
        Before I can finish my question, she shoots a glare at me with such ferocity that the words refuse to leave my mouth. I nod and leave.
    #Nod and leave.

Quinn awaits for me with a smile of a fox. The beer has not clouded ${q_his} gaze, a peculiar sight in itself. $!{q_his} eyes are sharp, ${q_his} voice low, almost a whisper: "Our Legate seems to have problems at home. Whatever to do with this information, I wonder—"
*goto ch2_tavern_brick

*label ch2_tavern_brick
A loud crash interrupts Quinn's smirk.

"What did ye say about my mother?!"

Brick has a Legionary soldier in a chokehold. The man's friends have turned the table over, ready for a fight. Floyd tries to yank Brick away from the man, all the while Kegan sleeps in a fetus position in the corner. Pec cheers at the scene with a keg of beer in his hand and once his eyes find mine, he mouths: 'A jolly good show!'

"Your friends are acting up," Quinn says in a dry voice, ${q_his} features mocking. "Are you going to help the sorry lot?"

*fake_choice
    #Interrupt the fight.
        *set group_friendship +5
        With a shake of my head I proceed to diffuse the situation.
        *label ch2_interrupt
        *fake_choice
            #Join Floyd to yank Brick away from the man.
                Floyd gives me a small nod before proceeding to yank the meatwall of a Brick off of the much smaller, but equally angry Legionary.
                
                Brick tries to kick me in the shin as I take a hold of him, but misses. "Get off of me, ya sorry piece of—"
                
                "Calm down!"
                
                "Calm down yerself—"
                
                It's no use, he's not budging. I need to think of something.
            #Order Pec to help.
                "You! Don't just stand there and grin like a fool, help us."
                
                Pec frowns at the command and the insult. With a sigh he stands up and takes a hold of Brick, who's by now shouting insults to everyone who tries to keep him pinned down.
                
                "Let go of me you sorry pieces of—"
                
                It's no use, he's not budging. I need to think of something.
            *disable_reuse #Command them all to stop.
                I muster all of the authority I have and shout: "Stop your foolishness at once!"
                
                But no one listens. No one even spares me a glance.
                *goto ch2_interrupt
            
        *fake_choice
            #Hit Brick in the head with a pint.
                *set brick_hitter true
                The clay shatters on the back of his head with a loud bang. Brick curses my mother, insults my gods, and cusses me into oblivion before falling to the beer-stained floor unconscious. Legionaries stare at the lifeless Brick before turning to me. I'm half-expecting them to continue the fight, but instead they give me a quick nod and leave the scene.
                
                Pec appears next to me, his eyes on the downed man. "Well, shit, Hati, remind me not to be on your bad side."
                
                Floyd is already on the ground checking if Brick is still breathing. "Wasn't that a bit of… unnecessary?" He pokes Brick on the cheek but gets no response.
                
                Pec scoffs as he kicks Brick on the shin. "It got the job done. He can only blame himself."
                
                Floyd sighs. "It did, I suppose. But now we have him and Kegan to carry back to the barracks."
                
                "You can basically hoist Kegan up with one hand," Pec dismisses the concern, but can't help but eye the downed brick of a man with some hesitation. This will be a long way back to the barracks.
            #Talk Brick down.
                *set brick_friend true
                I calm my voice and take a deep breath. What was it that he was so angered by? Something about his mother?
                
                "Brick!" I say with a raised tone. He glances at me, but it's enough to know that he's listening. It's already a win. "I understand that you love your mother."
                
                He halts his action and frowns. Breakthrough! I just need to keep talking. Floyd and Pec take the hint and move to cover Brick from the Legionaries, trying to calm them while I'm focused on the biggest obstacle. He's still in his fighting stance, but I've already coated his mind with hesitation.
                
                "You must miss her dearly."
                
                Brick's frown deepens and he gives me a solemn nod. His chest starts to rise quicker, but this time anger is not the one to cause the turmoil. "Mama has no one but me. I had to leave her alone—" He doesn't continue the sentence, nor does he need to. His eyes fill with tears.
                
                *fake_choice
                    #Hug him.
                        With no hesitation I close the distance between us and wrap my arms around him. His frame tenses only for a moment before melting in my arms. I understand how he feels. Leaving your family behind like that… His body starts to jerk, a telltale of crying, but I give him privacy and just squeeze him a little tighter. I ignore the snicker behind us, it's Pec probably, and keep hugging him for as long as he needs.
                        
                        Soon his muscles start to relax with his steadying breathing. It's as if he says something, but in such a small voice I barely hear it: 'Thank you.' As soon as the words reach my ears, he pushes me away from him and stomps away.
                    #"I'm sorry."
                        I understand how he feels. To leave your family behind like that… All I can do is to say I'm sorry. He gives me a small nod and the tears start running free, soaking his tunic in no time. As the sound of a quiet snicker reaches us, he shakes his head and starts stomping away.
                        
                        If I didn't know any better, I'd think he thanked me on the way.
                    #Nod. I feel a little bad for him.
                        It's a familiar story for a lot of men here, I suppose. At least for those who didn't come here voluntarily; Romans took them from their families. I can't help but to feel a little bad for him. He gives me a small nod in return and the tears start running free, soaking his tunic in no time. As the sound of a quiet snicker reaches us, he shakes his head and starts stomping away.                         
                        
                        If I didn't know any better, I'd think he thanked me on the way.
                    #Nod. Just get this over with.
                        I didn't expect him to start confiding in me. However, it's better to act somewhat interested in order to keep him from assaulting anyone further. So I give him a sympathetic nod, hoping it's enough to diffuse the situation. He gives me a small nod in return and the tears start running free, soaking his tunic in no time. As the sound of a quiet snicker reaches us, he shakes his head and starts stomping away.
                        
                        If I didn't know any better, I'd think he thanked me on the way.
                
                Floyd pats me on the shoulder. "You did good." He gives me an approving smile before leaving to help a slightly grimacing barmaid cleaning the mess the fighting soldiers left behind. She nods gratefully and continues the work with a little less of a frown on her face.
                
                Pec appears next to me "I wanted to see you tackle him or something," he says as his gaze lingers where Brick left. "I didn't know he was such a softie. Or you, for that matter. I'm surrounded by softies."
                
                Floyd sighs: "Don't start. Hati did better than I could've expected. You, on the other hand, did nothing more than encouraged the fight. Let's just forget about this, it's better for everyone."
                
                "Fine." Pec rolls his eyes.
            #Try to tackle him.
                *set brick_tackler true
                I take a hold of raging Brick's midsection as I hit him hard with my shoulder.
                
                *if build = "lithe"
                    "What the fuck do you think you're doing, squid?"
                    
                    He doesn't budge. I try to hit him again, but he keeps standing, barely even recognizing my efforts. He does, however, turn to me with his eyes almost bulging out of his sockets.
                    
                    "Are you defending the golden boys, squid? You wanna piece of this, too?" He shouts in his drunken stupor and shakes his fist in the air. Just as I'm about to deny my interest in getting hit by him, there's a sudden loud noise and he falls to the floor with a thump.
                    
                    Behind Brick there's Pec with a broken pint on his hand. He gives me a grin.
                    
                    "Oy, you needed a helping hand there?"
                    
                    *fake_choice
                        #"Thanks."
                            "No problem," he winks and continues to poke Brick's shin with his shoe. "Yeah, he's out of it."
                            
                            Floyd sighs. "You can't just hit someone unconscious and kick them for good measure."
                            
                            "I'm not kicking him, I'm checking if he's alive. He is, by the way. For what good that is worth."
                            
                            Floyd starts collecting the clay shards with a subtly grimacing barmaid. "You can't say that, he's your team mate."
                            
                            "Well, he just almost beat one of his own, I count that as a major loss in terms of team mateness." He gives me a another nod of his head and I can't help but give him a small smile in return. 
                        #"You didn't have to hit him in the head."
                            Floyd nods. "That was rash of you, Pec."
                            
                            Pec frowns as he pokes Brick's shin with his shoe. "Why are you ganging up on me? He would've beaten the shit out of Hati."
                            
                            "I wouldn't say he'd have gone that far," Floyd says, but there's a hint of hesitation in his tone. Every one of us know that he would've tried to, at least. It's hard to say if he has something specific against me or if he's just angry at the world. I guess I can almost relate.
                            
                    Floyd sighs. "Now we have him and Kegan to carry back to the barracks."
                
                    "You can basically hoist Kegan up with one hand," Pec dismisses the concern, but can't help but eye the downed brick of a man with some hesitation. This will be a long way back to the barracks.
                *if build = "average"
                    He barely moves by my efforts.
                    
                    "What the—" He shouts, but I hit him again, this time with more vigor to get the seething man to fall down, kicking his foot in the process. Finally his drunken wobbly legs give in and I fall to the ground with him. There's a thump as his head hits the floor, and he falls silent.
                    
                    Quietness finally falls to the tavern as Brick has been conquered. A barmaid walks up to the downed table, subtly shaking her head and starts collecting the clay shards. Legionaries stare at the lifeless Brick before turning to me. I'm half-expecting them to continue the fight, but instead they give me a quick nod and leave the scene.
                    
                    "Man, that was impressive, Hati," Pec says with a wide grin. "You tackled that prick with no hesitation."
                    
                    Floyd sighs as he helps the barmaid, whose frown has lost some of its potency now that she has a pair of hands helping her. Floyd shakes his head. "Now we have him and Kegan to carry back to the barracks."
                
                    "You can basically hoist Kegan up with one hand," Pec dismisses the concern, but can't help but eye the downed brick of a man with some hesitation. This will be a long way back to the barracks.
                *if build = "heavy"
                    I tackle him easily, giving his drunken mind no time to register what happened when he's already on the beer-stained floor. There's a loud thump as his head hits the floor, and he falls silent. 
                    
                    Quietness finally falls to the tavern as Brick has been conquered. A barmaid walks up to the downed table, subtly shaking her head and starts collecting the clay shards. Legionaries stare at the lifeless Brick before turning to me. I'm half-expecting them to continue the fight, but instead they give me a quick nod and leave the scene.
                    
                    "Well, shit, Hati!" An enthusiastic shout follows the downfall of Brick. Pec helps me up with a wide grin. "That was so impressive! You just tackled him like crazy!"
                    
                    Floyd sighs as he helps the barmaid, whose frown has lost some of its potency now that she has a pair of hands helping her. Floyd shakes his head. "Now we have him and Kegan to carry back to the barracks."
                    
                    "You can basically hoist Kegan up with one hand," Pec dismisses the concern, but can't help but eye the downed brick of a man with some hesitation. This will be a long way back to the barracks.
                
    #Ignore it and leave.
        "Not my problem."
        
        Quinn grins and gives me a nod of appreciation. "Indeed. Let's leave before they wreck up the place."
        
        Quinn walks ahead towards the door with a surprisingly steady stride. Before I follow, I take a moment to register Floyd giving me a disappointed look as he tries to keep the charging Brick down. 
        
        Whatever. It's not like it's my duty to babysit them.
        
        I turn to leave the chaos behind.
*page_break
*goto_scene chapter_2 ch2_tinsae